بررسی حالت Deep Sleep در برد ESP32 و روش‌های بیدار کردن آن

/* 
Modified on Jul 12, 2021
Modified by MehranMaleki from Arduino Examples
Home

*/


#define Threshold 40 /* Greater the value, more the sensitivity */


RTC_DATA_ATTR int bootCount = 0;


//Function for printing the reason by which ESP32 has been awakened from sleep
void print_wakeup_reason(){
 esp_sleep_wakeup_cause_t wakeup_reason;

 wakeup_reason = esp_sleep_get_wakeup_cause();

 switch(wakeup_reason)
 {
 case ESP_SLEEP_WAKEUP_EXT0 : Serial.println("Wakeup caused by external signal using RTC_IO"); break;
 case ESP_SLEEP_WAKEUP_EXT1 : Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
 case ESP_SLEEP_WAKEUP_TIMER : Serial.println("Wakeup caused by timer"); break;
 case ESP_SLEEP_WAKEUP_TOUCHPAD : Serial.println("Wakeup caused by touchpad"); break;
 case ESP_SLEEP_WAKEUP_ULP : Serial.println("Wakeup caused by ULP program"); break;
 default : Serial.printf("Wakeup was not caused by deep sleep: %d\n",wakeup_reason); break;
 }
}


//Function for printing the touchpad by which ESP32 has been awakened from sleep
void print_wakeup_touchpad(){
 touch_pad_t touchPin;
 touchPin = esp_sleep_get_touchpad_wakeup_status();

 switch(touchPin)
 {
 case 0 : Serial.println("Touch detected on GPIO 4"); break;
 case 1 : Serial.println("Touch detected on GPIO 0"); break;
 case 2 : Serial.println("Touch detected on GPIO 2"); break;
 case 3 : Serial.println("Touch detected on GPIO 15"); break;
 case 4 : Serial.println("Touch detected on GPIO 13"); break;
 case 5 : Serial.println("Touch detected on GPIO 12"); break;
 case 6 : Serial.println("Touch detected on GPIO 14"); break;
 case 7 : Serial.println("Touch detected on GPIO 27"); break;
 case 8 : Serial.println("Touch detected on GPIO 33"); break;
 case 9 : Serial.println("Touch detected on GPIO 32"); break;
 default : Serial.println("Wakeup not by touchpad"); break;
 }
}

void callback(){
 //write instructions you want to be performed when the ESP32 wakes up
}

void setup(){
 Serial.begin(115200);
 delay(500);

 //Increment boot number and print it every reboot
 bootCount++;
 Serial.println("Boot number: " + String(bootCount));

 //Print the wakeup reason for ESP32 and aslo the touchpad
 print_wakeup_reason();
 print_wakeup_touchpad();


 /*
 1st Step: we should configure the wake up source:
 We set our ESP32 to use "TouchPad 3 (GPIO15)" to wake up
 To do that, we first need to setup interrupt on one of
 the touch pins -in our case "Touch Pad 3"- and then,
 configure "Touchpad" as the wakeup source.
 */
 //Setup interrupt on Touch Pad 3 (GPIO15)
 touchAttachInterrupt(T3, callback, Threshold);
 //Configure Touchpad as wakeup source
 esp_sleep_enable_touchpad_wakeup();

 
 /*
 2nd Step: we can decide what peripherals to shut down or keep on.
 By default, ESP32 will automatically power down all peripherals
 not needed by the wakeup source. But if you want to configure peripherals
 on your own, read the details in the API docs:
 http://esp-idf.readthedocs.io/en/latest/api-reference/system/deep_sleep.html
 The comment line below is an example of how to configure peripherals. It
 turns off all RTC peripherals in deep sleep mode. You can leave that comment.
 */
 //esp_deep_sleep_pd_config(ESP_PD_DOMAIN_RTC_PERIPH, ESP_PD_OPTION_OFF);


 /*
 3rd Step: Now that we have set up a wake cause, and if needed, setup the
 peripherals state in deep sleep mode, we can now start going to
 deep sleep.
 If you have provided no wake up sources but the deep
 sleep has been started, it will sleep forever unless hardware
 reset occurs.
 */
 Serial.println("Going to sleep now");
 delay(500);
 esp_deep_sleep_start();
 Serial.println("This will never be printed");
}

void loop(){
 //This will not be used in Deep Sleep mode.
}